menu 的 子 item 可以从数据库提取么解决思路

本文拟结合POWERBUILDER语言，简述如何实现动态添加菜单效果。在实际开发过程当中很多时候会因为权限控制的需要，根据用户的不同权限来动态添加菜单项目，如何避免使用繁琐的API函数（如：CreateMenu、InsertMenu、InsertMenuItem、AppendMenu等），利用POWERBUILDER语言自身功能达到这一目的呢？本文将就此问题简单予以论述。
一、基本思路
在PB帮助的MENU OBJECT一节当中，关于其PROPERTIES描述当中有一项：
Item[ ]    Menu    Specifies the Menu objects under a Menu object.
这看似简单的一句话其实包含了三层含义：
1、这句话说明MENU对象有一个属性为数组类型，它其中的各个元素记录了其所有的具体子ITEM项目，可以借助这个数组中各元素来访问底层的各子菜单；
2、这些子ITEM项目仍是MENU类型，因此可以按照第一点的逻辑继续向下层推广，借助该子ITEM的ITEM[]属性可以进而访问其所属下层的第二层子菜单，推而广之，即可全面遍历整个菜单体系的所有子菜单项目；
3、既然该属性是一个数组类型，那么就可以按照数组类型变量来处理，我们可以对其进行upperbound()、lowerbound()等函数操作，还可以进行数组的扩展，即添加新项目，这一点很重要，它是我们整篇文章的核心，如何利用PB实现动态添加菜单，说白了就是添加这个数组元素（读者必须对此有一个清晰的认识），同时期间有一些配套具体的实现技巧，详见下文。
二、具体实现
（一）基本工作
创建一个WINDOW窗口和二个MENU菜单，其中一个菜单命名为m_main，用作窗口的基本主菜单，新增菜单将在其上添加，该菜单初始可以包含一些基本菜单，如：文件、添加、删除、保存、退出等；另外一个菜单命名为m_new，该菜单只有主菜单一个ITEM，其下没有进一步的子菜单，因此该菜单其实就是一个菜单ITEM。
在主窗口中声明实例变量（INSTANCE VARIABLES）：
menu im_new[] //声明一菜单数组用于引用新增菜单
integer ii_count //声明一变量记录总共新增菜单个数
（二）具体代码
1、添加一级菜单功能的实现：
//////////////////////////////////////////////
//
//用途：在最后一项以及菜单之后新增一项一级菜单
//时间：2003-6-1
//
//////////////////////////////////////////////

integer li_itemcount  //声明变量记录当前一级菜单总个数； 

//新创建一个菜单对象，并将其放到菜单数组im_new[]当中；
ii_count++
im_new[ii_count]=create m_new

//此处对新创建的菜单对象获取引用；
li_itemcount=upperbound(m_main.item[])
m_main.item[li_itemcount + 1]=im_new[ii_count].item[1]

//下面是设置新生成菜单的TEXT属性，这个属性可以从数据库中取，但此处省略简化掉了；
m_main.item[li_itemcount + 1].text="新增一级-" + string(li_itemcount + 1)

//下面是设置新生成菜单的TAG属性，这个属性可以从数据库中取，但此处省略简化掉了；
//通过这个TAG可以当作功能号等来使用，通过gf_menumessage()函数来予以公共处理；
//m_main.item[li_itemcount + 1].tag="xxxxxxxxx"

//此处来将新生成的菜单对象显示出来；
m_main.item[1].hide()
m_main.item[1].show()
2、添加二级菜单功能的实现：
//////////////////////////////////////////////
//
//用途：在最后一项一级菜单下新增一项二级菜单
//时间：2003-6-1
//
//////////////////////////////////////////////

//声明变量记录当前一级菜单总个数、最后一项一级菜单对应的二级菜单总个数； 
integer li_precount,li_itemcount

//新创建一个菜单对象，并将其放到菜单数组im_new[]当中；
ii_count++
im_new[ii_count]=create m_new

//此处对新创建的菜单对象获取引用；
li_precount=upperbound(m_main.item[])
li_itemcount=upperbound(m_main.item[li_precount].item[])
m_main.item[li_precount].item[li_itemcount + 1]=im_new[ii_count].item[1]

//下面是设置新生成菜单的TEXT属性，这个属性可以从数据库中取，但此处省略简化掉了；
m_main.item[li_precount].item[li_itemcount + 1].text="新增二级-" + string(li_precount) + "-" + string(li_itemcount + 1)

//下面是设置新生成菜单的TAG属性，这个属性可以从数据库中取，但此处省略简化掉了；
//通过这个TAG可以当作功能号等来使用，通过gf_menumessage()函数来予以公共处理；
//m_main.item[li_precount].item[li_itemcount + 1].tag="xxxxxxxxx"

//此处来将新生成的菜单对象显示出来；
m_main.item[1].hide()
m_main.item[1].show()
3、添加三级菜单功能的实现：
//////////////////////////////////////////////
//
//用途：在最后一项二级菜单下新增一项三级菜单
//时间：2003-6-1
//
//////////////////////////////////////////////

//声明变量记录当前一级菜单总个数、最后一项一级菜单对应的二级菜单总个数； 
integer li_fircount,li_precount,li_itemcount

//新创建一个菜单对象，并将其放到菜单数组im_new[]当中；
ii_count++
im_new[ii_count]=create m_new

//此处对新创建的菜单对象获取引用；
li_fircount=upperbound(m_main.item[])
li_precount=upperbound(m_main.item[li_fircount].item[])
if li_precount = 0 then
    messagebox("提示","请先点击-添加二级菜单-按钮创建一个二级菜单，：）")
    return
end if
li_itemcount=upperbound(m_main.item[li_fircount].item[li_precount].item[])
m_main.item[li_fircount].item[li_precount].item[li_itemcount + 1]=im_new[ii_count].item[1]

//下面是设置新生成菜单的TEXT属性，这个属性可以从数据库中取，但此处省略简化掉了；
m_main.item[li_fircount].item[li_precount].item[li_itemcount + 1].text="新增三级-" + string(li_fircount) &
                                              + "-" + string(li_precount) + "-" + string(li_itemcount + 1)

//下面是设置新生成菜单的TAG属性，这个属性可以从数据库中取，但此处省略简化掉了；
//通过这个TAG可以当作功能号等来使用，通过gf_menumessage()函数来予以公共处理；
//m_main.item[li_precount].item[li_itemcount + 1].tag="xxxxxxxxx"

//此处来将新生成的菜单对象显示出来；
m_main.item[1].hide()
m_main.item[1].show()
4、处理动态生成菜单的CLICKED事件：
总体思想是采用参数化思想，借助统一的函数，根据函数参数不同来予以不同处理。
（1）处理m_new对象的clicked事件：
////////////////////////////////////////////////////////////////////////
//
//用途：根据新生成的各菜单所对应的功能号，即从数据库中取出的TAG属性
//      来调用gf_menumessage()全局函数来实现不同的系统功能；
//时间：2003-6-1
//
////////////////////////////////////////////////////////////////////////

//此处本应该去调用gf_menumessage()全局函数来处理不同功能所对应要处理的功能号，
//但此处均略掉了，具体内容可参见 gf_menumessage() 函数；
//此处仅仅演示一个messagebox()功能，如下；
//integer li_ret

//li_ret = gf_menumessage(this.tag)

//下面代码是避免点击含有下一级子菜单的菜单时会弹出对话框，导致无法显示下一级菜单的情况；
if upperbound(this.item[]) > 0 then
    return
end if

messagebox("动态菜单演示","您当前点击的菜单是：" + this.text)
（2）编写gf_menumessage函数：
////////////////////////////////////////////////////////////////////////
//
//用途：根据新生成的各菜单所对应传进来的功能号，即从数据库中取出的TAG属性
//      来动态判断所要进行的操作；
//时间：2003-6-1
//输入：string 型 as_funcode:对应传进来的菜单要实现的功能号；
//输出：integer型  1:成功
//                -1:失败
//
////////////////////////////////////////////////////////////////////////

//注：根据新生成的各菜单所对应传进来的功能号，即从数据库中取出的TAG属性
//    来动态判断所要进行的操作；此操作需要连接数据库，故此处简列思路，具体略

string ls_funcode //声明一变量用于记录传进来的功能号；

ls_funcode = as_funcode

choose case ls_funcode
    case "1"
        //......比如 1 代表入库管理，则去调用入库管理函数 gf_rk()等等
    case "2"
        //......比如 1 代表出库管理，则去调用出库管理函数 gf_ck()等等
    //......
   case else
        return -1
end choose

return 1